From fde3e045d4dcc5c404cb4216389e18b0e720b8e0 Mon Sep 17 00:00:00 2001
From: Richard-Qin-X <richard.qin.001@gmail.com>
Date: Thu, 13 Aug 2026 12:55:12 +0800
Subject: [IR] Split LL parsing, assembly writing, and data layout

---
 backend/lib/AsmParser/CMakeLists.txt | 41 ++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 backend/lib/AsmParser/CMakeLists.txt

(limited to 'backend/lib/AsmParser/CMakeLists.txt')

diff --git a/backend/lib/AsmParser/CMakeLists.txt b/backend/lib/AsmParser/CMakeLists.txt
new file mode 100644
index 0000000..d35fa24
--- /dev/null
+++ b/backend/lib/AsmParser/CMakeLists.txt
@@ -0,0 +1,41 @@
+# SPDX-License-Identifier: GPL-3.0-or-later
+
+set(RCCBackendAsmParserSources LLParser.cpp)
+set(
+  RCCBackendAsmParserHeaders
+  "${RCC_BACKEND_SOURCE_DIR}/include/rcc/AsmParser/LLParser.h"
+)
+
+add_library(RCCBackendAsmParser ${RCCBackendAsmParserSources})
+add_library(RCCBackend::AsmParser ALIAS RCCBackendAsmParser)
+
+rcc_backend_configure_target(RCCBackendAsmParser)
+
+target_include_directories(
+  RCCBackendAsmParser
+  PUBLIC
+    "$<BUILD_INTERFACE:${RCC_BACKEND_SOURCE_DIR}/include>"
+    "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
+)
+target_link_libraries(RCCBackendAsmParser PUBLIC RCCBackend::IR)
+
+set_target_properties(
+  RCCBackendAsmParser
+  PROPERTIES
+    EXPORT_NAME AsmParser
+    OUTPUT_NAME RCCBackendAsmParser
+)
+
+install(
+  TARGETS RCCBackendAsmParser
+  EXPORT RCCBackendTargets
+  ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+  LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+  RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+)
+
+rcc_backend_register_format_files(
+  "${CMAKE_CURRENT_SOURCE_DIR}/LLParser.cpp"
+  ${RCCBackendAsmParserHeaders}
+)
+rcc_backend_register_tidy_files("${CMAKE_CURRENT_SOURCE_DIR}/LLParser.cpp")
-- 
cgit v1.2.3